Restore Point - Add "Create Restore Point" to Context Menu in Windows

Brink said:

Nar, you shouldn't. Option Two will undo it if you should ever want to. :)

Your the best i have the removal saved so Im sure it will work as the tutorial says.

Hello Shawn,

Any chance to have something similar for windows 10?

Thanks

Hi, I don't mean to be too critical but I tried this and System Restore Manager and none of these methodswork. I am trying to say "where is the created restore point" and how do I access it to restore the computer if need be. My neighbor is standing right behind me and he said, " you followed all the directions to a tee, what gives. I guess what I am trying to narrow down, is, where is this created file, OK< please help, surely a dimple explanation....I don't have any system restore stuff so maybe this is mucking up the works, psongman

Yeah, there are restore points created but no way to access them. I mean everyone who helps out, I get to a point and then do the creating, and you can see it working, but absolutely no way to access them in all the system settings, they must be some place, eheh, getting my sense of humor back, probably in recovery mode which I will be tomorrow after I exit this mission, mission seeming impossible, psongman

Update for Windows 10

Code:

' Created by: Shawn Brink
' https://www.sevenforums.com
' Tutorial: https://www.sevenforums.com/tutorials/285911-restore-point-add-create-restore-point-context-menu-windows.html
' Version 2.0 - Updated by war59312 for Windows 10 Support

Function GetOS
    Set objWMI = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & ".\root\cimv2")
    Set colOS = objWMI.ExecQuery("Select * from Win32_OperatingSystem")
    For Each objOS in colOS
        If instr(objOS.Caption, "Windows 10") Then
        	GetOS = "Windows 10"
        elseIf instr(objOS.Caption, "Windows 8") Then
        	GetOS = "Windows 8"
        elseIf instr(objOS.Caption, "Windows 7") Then
        	GetOS = "Windows 7"
        elseIf instr(objOS.Caption, "Vista") Then
        	GetOS = "Windows Vista"
        elseIf instr(objOS.Caption, "Windows XP") Then
      		GetOS = "Windows XP"
        End If
	Next
End Function

If GetOS = "Windows XP" Then
	CreateSRP
End If

If GetOS = "Windows Vista" Or GetOS = "Windows 7" Then
	If WScript.Arguments.length =0 Then
  		Set objShell = CreateObject("Shell.Application")
		objShell.ShellExecute "wscript.exe", Chr(34) & WScript.ScriptFullName & Chr(34) & " Run", , "runas", 1
	Else
  		CreateSRP
  	End If
End If

If GetOS = "Windows 8" Or GetOS = "Windows 10" Then
	If WScript.Arguments.length =0 Then
  		Set objShell = CreateObject("Shell.Application")
		objShell.ShellExecute "wscript.exe", Chr(34) & WScript.ScriptFullName & Chr(34) & " Run", , "runas", 1
         Else
               const HKEY_LOCAL_MACHINE = &H80000002
               strComputer = "."
               Set oReg=GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\default:StdRegProv")
               strKeyPath = "SOFTWARE\Microsoft\Windows NT\CurrentVersion\SystemRestore"
               strValueName = "SystemRestorePointCreationFrequency"
               oReg.SetDWORDValue HKEY_LOCAL_MACHINE,strKeyPath,strValueName,0
        CreateSRP
  	End If
End If

Sub CreateSRP
	Set SRP = getobject("winmgmts:\\.\root\default:Systemrestore")
	sDesc = "Manual Restore Point"
	sDesc = InputBox ("Enter a restore point description.", "Create Manual System Restore Point","Manual Restore Point")
	If Trim(sDesc) <> "" Then
		sOut = SRP.createrestorepoint (sDesc, 0, 100)
		If sOut <> 0 Then
	 		WScript.echo "Error " & sOut & ": Unable to create Restore Point."
                else
                MsgBox "The restore point was created successfully.", 0, "Create Manual System Restore Point"
		End If
	End If
End Sub