shutdown and restart of network PCs

[namich2007]

Hi there,

I oversee a small test facility of about 200 systems running a mix of XP, Vista and Win 7. They are all on the same Lan / subnet and all configure with a static ip address.

What i want to achieve is a batch shut down and restart of these systems from a central workstation which is also on the same lan.

Can someone point me in the right direction.

Thanks

 

[Kari]

Only built-in command which can be found on all those three OS's I can think of is shutdown -i, which opens the remote shutdown dialog:



Have you tried this?

Kari

 

[namich2007]

Hey Kari,

I tried your suggestion and was able to get it working for my XP pro Sp3 systems. However I have had no luck with the Vista Home Basic and Win 7 home premium systems. Do you think that because my Vista and Win 7 systems are not the professional versions may be why the shutdown command is not working?

 

[Kari]

I have to check this. I have both Vistas and Sevens running at home, but all Ultimates and a Seven enterprise, so I can not test it myself.

I ask some fellow geeks, posting back when I know.

Kari

 

[Barman58]

I can confirm from experience that the command does work on Vista home Premium.

One thing you may need to ensure is that the user is an admin and has an account on all systems, assuming a non domain environment when I believe that a domain admin account may be required.

Additional Information

You may also need to enable WMI remote management, this can be achived with the following ...

netsh advfirewall firewall set rule group="windows management instrumentation (WMI)" new enable=Yes

Also open any ports in the firewall relating to remote management using the advanced firewall options

 

[Kari]

I thought it should work on all editions. Thanks for confirming that, Nigel.

 

[Barman58]

Additional info added - it's been a while since I set one up

 

[namich2007]

I have disable windows firewall all together and set up an admin account on all remote workstations with the same credentials as that used on the control workstation. When I run :

shutdown.exe -r -f -t 00 -m \\192.168.12.xxx

response : the network path was not found

 

[Barman58]

The spec for the command gives the parameter as \\computername rather than IP address - I always used the \\computername so it maybe that the IP is not supported although this would be unusual.

 

[WindowsStar]

The spec for the command gives the parameter as \\computername rather than IP address - I always used the \\computername so it maybe that the IP is not supported although this would be unusual.

I can confirm IP is supported I use it all the time.

I have a script for this...let me dig it up.

 

[WindowsStar]

OP are you on a domain or not??

 

[WindowsStar]

You will need to prep the machines for this to work:

Windows XP or Windows Server 2003 or Windows Server 2003 R2:

Logon as Administrator and run from a Command Prompt:
netsh firewall set service RemoteAdmin enable

Windows Vista or Windows 7 or Windows Server 2008 or Windows Server 2008 R2

Run as Administrator and run from a Command Prompt
netsh advfirewall firewall set rule group="windows management instrumentation (WMI)" new enable=Yes

and

netsh advfirewall firewall set rule group=”File and Printer Sharing” new enable=Yes

Now let me find the script to for rebooting.

Until then you can use shutdown -m \\<computername> or <IP> -r -f -t 0

 

[namich2007]

unfortunately I am not running the workstations in a domain environment. There all in a workgroup.

 

[WindowsStar]

Ok here is the script. I had to modify it for non-domain. It seems to work but it has not been toughly tested.

The nice thing about scheduling the reboot is that you can set it up for a reboot in 2 minutes or late at night when you are asleep or to reboot 10 hours later when you might forget. I spent a lot of time getting this to work and it has worked very well for me over the years.

Please give it a good test and let me know.

' Schedule Computer Reboot v3.9
' Programmed by WindowsStar - Copyright (c) 2008-2010
'
'"netsh firewall set service RemoteAdmin enable" (Must be run at the command prompt on Window XP or Server 2003 before this will work)
' Must enable "Windows Management Instrumentation (WMI)" and "File and Printer Sharing" on Vista or Server 2008 Firewall before this will work)
' --------------------------------------------------------
Set Login = Wscript.CreateObject("WSHLogin.clsLogin")
Set WSHShell = WScript.CreateObject("WScript.Shell")
Set WShNetwork = CreateObject("WScript.Network")
Set fso = CreateObject("Scripting.FileSystemObject")
Set objEnv = WshShell.Environment("Process")
DSTOffset = "420"
Title = "Computer Name"
Message = "Name of computer to reboot." & vbLF & vbLF & "Leave blank or press cancel to quit."
strComputer = UCase(InputBox(Message, Title, WShNetwork.ComputerName))
If strComputer = "" Then Wscript.quit
Title = "Reboot Time"
Message = "Enter reboot time in military format." & vbLF & vbLF & "Sample: 05:45" & vbLF & "Sample: 14:45" & vbLF & vbLF & "Leave blank or press cancel to quit."
strTime = InputBox(Message, Title, "")
If strTime = "" Then Wscript.quit
strNormalTime = strTime
strTime = Left(Replace(strTime,":","") & "0000",6)
If Left(strTime,2) > 23 Then WScript.Echo "Incorrect time entered! Script Terminated!" : WScript.Quit
If Mid(strTime,3,2) > 59 Then WScript.Echo "Incorrect time entered! Script Terminated!" : WScript.Quit
'On Error Resume Next
Set objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
Set colItems = objWMIService.ExecQuery("SELECT * FROM Win32_ComputerSystem")
For Each objItem In colItems
  If objItem.DaylightInEffect = True Then DSTOffset = "360"
Next
Set colItems = objWMIService.ExecQuery("Select * from Win32_OperatingSystem",,48)
For Each objItem in colItems
  If LCase(InStr(objItem.Caption,"Windows XP")) or LCase(InStr(objItem.Caption,"Vista")) Then
    Set objNewJob = objWMIService.Get("Win32_ScheduledJob")
    errJobCreated = objNewJob.Create ("shutdown.exe -r -f -t 05", "********" & strTime & ".000000-" & DSTOffset, False , , , False, JobId)
  End If
Next
Set colItems = objWMIService.ExecQuery("Select * from Win32_OperatingSystem",,48)
For Each objItem in colItems
  If LCase(InStr(objItem.Caption,"Windows 2000")) or LCase(InStr(objItem.Caption,"Server 2003")) Then
    Set objNewJob = objWMIService.Get("Win32_ScheduledJob")
    errJobCreated = objNewJob.Create ("shutdown.exe /r /f /t 05", "********" & strTime & ".000000-" & DSTOffset, False , , , False, JobId)
  End If
Next
Set colItems = objWMIService.ExecQuery("Select * from Win32_OperatingSystem",,48)
For Each objItem in colItems
  If LCase(InStr(objItem.Caption,"Windows 7")) or LCase(InStr(objItem.Caption,"Server 2008 R2")) Then
     Set objProcess = objWMIService.Get("Win32_Process")
     strCommand = "SCHTASKS /Create /SC ONCE /TN Scheduled-Reboot /F /NP /RL HIGHEST /TR " & Chr(34) & "shutdown.exe -r -f -t 05" & Chr(34) & " /ST " & strNormalTime
     errReturn = objProcess.Create(strCommand, null, null, intProcessID)
  End If
Next
If errReturn <> 0 Then WScript.Echo "Reboot NOT Scheduled!  " & Err.Number : WScript.Quit
If Err.Number <> 0 Then WScript.Echo "Reboot NOT Scheduled!  " & Err.Number : WScript.Quit
WShNetwork.MapNetworkDrive "", "\\" & strComputer & "\IPC$"
If fso.FileExists ("\\" & strComputer & "\C$\Windows\Tasks\At1.job") Then fso.MoveFile "\\" & strComputer & "\C$\Windows\Tasks\At1.job", "\\" & strComputer & "\C$\Windows\Tasks\Scheduled Reboot.job"
If fso.FileExists ("\\" & strComputer & "\C$\Winnt\Tasks\At1.job") Then fso.MoveFile "\\" & strComputer & "\C$\Winnt\Tasks\At1.job", "\\" & strComputer & "\C$\Winnt\Tasks\Scheduled Reboot.job"
WShNetwork.RemoveNetworkDrive "\\" & strComputer & "\IPC$"
On Error Resume Next
fso.DeleteFile(objEnv("UserProfile") & "\Recent\*.lnk"), True
fso.DeleteFile(objEnv("UserProfile") & "\AppData\Roaming\Microsoft\Windows\Recent\*.lnk"), True
WshShell.Popup "           Done!",5,"Script Message"