Re-Installing O/S: Do I lose programs such as WORD?

[Chaim613]

Hello,
My Windows 7 is out of warranty, so I will have to pay for the answer to this problem if I go to Microsoft Support:

PROBLEM:
I would like to re-install my Windows 7 Pro O/S but I am afraid if I do so I will lose the Microsoft WORD program.

I don’t want to re-purchase WORD.

Is there some way to have WORD on my system after I re-install the O/S without paying for a new WORD installation disk?


If I lose WORD I know I can go to Open Office.

Thanx

 

[derekimo]

You could run Belarc advisor to find the product key for word,

Belarc Advisor - Free Personal PC Audit, for software, hardware and security configuration information on your computer. Software license management, IT asset management, cyber security audits, and more.

 

[Ztruker]

Download and run this script. It will show you your key without needing Belarc, though Belarc is a very good progrm to have around.

https://dl.dropboxusercontent.com/u/110470324/ShowKey.vbs

Or create a ShowKey.vbs from the following code:

Set WshShell = CreateObject("WScript.Shell")
Key = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"
DigitalID = WshShell.RegRead(key & "DigitalProductId")

ProductName = "Product Name: " & WshShell.RegRead(Key & "ProductName") & vbNewLine
ProductID = "Product ID: " & WshShell.RegRead(Key & "ProductID") & vbNewLine
ProductKey = "Installed Key: " & ConvertToKey(DigitalID)
ProductID = ProductName & ProductID & ProductKey

If vbYes = MsgBox(ProductId & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "Windows Key Information") then
   Save ProductID
End if

Function ConvertToKey(Key)
    Const KeyOffset = 52
    isWin8 = (Key(66) \ 6) And 1
    Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4)
    i = 24
    Chars = "BCDFGHJKMPQRTVWXY2346789"
    Do
        Cur = 0
        X = 14
        Do
            Cur = Cur * 256
            Cur = Key(X + KeyOffset) + Cur
            Key(X + KeyOffset) = (Cur \ 24)
            Cur = Cur Mod 24
            X = X -1
        Loop While X >= 0
        i = i -1
        KeyOutput = Mid(Chars, Cur + 1, 1) & KeyOutput
        Last = Cur
    Loop While i >= 0
    If (isWin8 = 1) Then
        keypart1 = Mid(KeyOutput, 2, Last)
        insert = "N"
        KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0)
        If Last = 0 Then KeyOutput = insert & KeyOutput
    End If
    a = Mid(KeyOutput, 1, 5)
    b = Mid(KeyOutput, 6, 5)
    c = Mid(KeyOutput, 11, 5)
    d = Mid(KeyOutput, 16, 5)
    e = Mid(KeyOutput, 21, 5)
    ConvertToKey = a & "-" & b & "-" & c & "-" & d & "-" & e
End Function

Function Save(Data)
    Const ForWRITING = 2
    Const asASCII = 0
    Dim fso, f, fName, ts
    fName = "Windows Key.txt"
    Set fso = CreateObject("Scripting.FileSystemObject")
    fso.CreateTextFile fName
    Set f = fso.GetFile(fName)
    Set f = f.OpenAsTextStream(ForWRITING, asASCII)
    f.Writeline Data
    f.Close
End Function

I don't remember who posted this originally so I can't provide proper attribution, sorry.

 

[derekimo]

That works great for the OS, can you get it to grab office keys too?

 

[gregrocker]

Like Win7 you own Office for life, to be reinstalled as often and wherever you like.

Everything that needs to be considered for backing up and then getting and keeping a perfect reinstall is in Clean Reinstall - Factory OEM Windows 7 and are the same steps for retail.
http://www.sevenforums.com/tutorials/219487-clean-reinstall-factory-oem-windows-7-a.html#post1839164

 

[Ztruker]

I have Office 2007, and this script shows the correct key on my Windows 8 Pro X64 system:

Set WshShell = CreateObject("WScript.Shell")
MsgBox ConvertToKey(WshShell.RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Microsoft\Office\12.0\Registration\{91120000-0031-0000-0000-0000000FF1CE}\DigitalProductID"))
 
Function ConvertToKey(Key)
    Const KeyOffset = 52
    i = 28
    Chars = "BCDFGHJKMPQRTVWXY2346789"
    Do
        Cur = 0
        x = 14
        Do
            Cur = Cur * 256
            Cur = Key(x + KeyOffset) + Cur
            Key(x + KeyOffset) = (Cur \ 24) And 255
            Cur = Cur Mod 24
            x = x -1
        Loop While x >= 0
        i = i -1
        KeyOutput = Mid(Chars, Cur + 1, 1) & KeyOutput
        If (((29 - i) Mod 6) = 0) And (i <> -1) Then
            i = i -1
            KeyOutput = "-" & KeyOutput
        End If
    Loop While i >= 0
    ConvertToKey = KeyOutput
End Function

The reg key path will be different for X86 systems, but I don't have any to check with. Open regedit and search for DigitalProductID, that should get you to the right key to use.

Above script found here: http://forums.mydigitallife.info/printthread.php?t=7520&pp=10&page=2